使用Groovy实现自己的DSL
这段时间在学习构建工具Gradle，因为Gradle的构建脚本要使用到groovy语言编写，因此就顺便学习了一下groovy。一开始听说gradle脚本其实就是groovy语言的脚本，我是十分震惊的，因为再怎么看都感觉build.gradle都只是像一个配置文件，根本想不到是一段代码。学习了gradle里面的各种特殊的省略写法和闭包的概念之后，才恍然大悟，原来.gradle脚本就是各种省略完了的groovy脚本。
定义成DSL的好处时，让就算没学过Groovy语法的非专业用户也能非常方便直观地，使用接近自然语言的魔法语法来编写代码组织功能。因为听起来真的很cool，我就也尝试自己写了一套用于绘制简单的线段图形的DSL。这个想法来源于《程序员修炼之道》这本书，书中在介绍领域语言的时候引入了一个类似的练习。
目标
使用Groovy定义一套DSL，让下面的脚本可以绘制出直线并展示出来。
1pad(500, 500) {
2 color "black"
3 line {
4 start(100, 200) end(300, 300)
5 start(100, 30) end(0, 0)
6 }
7 color "red"
8 line {
9 start(100, 200) end(100, 300)
10 start(500, 500) end(60, 20)
11 }
12}
13
14pad {
15 size {
16 length = 1000
17 width = 1000
18 }
19 color "red"
20 line {
21 start(100, 200) end(300, 300)
22 }
23}
进行一下简单说明：
- pad表示一个新建一个画板，花括号中表示这个画板上的内容
- 画板的大小既可以在建立的时候通过圆括号指定，也可以在内容中用size来指定
- color表示更换颜色，表示之后的绘图将使用新的颜色。默认黑色
- start end表示一条线段开始和结束的坐标，放在line后的块可以定义line
Step0 打桩
直接运行脚本必定报错，首先想办法让脚本不报错。这里打桩的方法是建立一个脚本，用来写自己的DSL实现，然后在现在的类中通过静态引入的方式，将dsl脚本引入。
1// SimpleTest.groovy
2import static top.claws.PaintingDsl.*
3
4pad(500, 500) {
5 color "black"
6 //......
7}
然后在PaintingDsl中，先定义静态的pad函数。
1class PaintingDsl {
2 static def pad(def length, def width, Closure closure) {
3 // TODO
4 }
5
6 static def pad(Closure closure) {
7 // TODO
8 }
9}
这里牵扯到Groovy中的省略：
- 如果一个函数最后一个参数是闭包，这个闭包在调用的时候可以写在外面。
- 如果一个函数调用有且只有一个参数，则函数调用的括号可以省略。
这样，pad {...}和pad(500, 500) {...} 类似的写法就都不会报错了。
Step1 绘制第一条直线
先不管pad中的内容是怎么样的，想办法可以用java的库来绘制展示第一条直线试试。
1package top.claws
2
3import javax.swing.JFrame
4import javax.swing.JPanel
5import java.awt.Color
6import java.awt.Graphics
7
8class PaintingDsl {
9 def length
10 def width
11
12 PaintingDsl(length, width) {
13 this.length = length
14 this.width = width
15 }
16
17 static def pad(def length, def width, Closure closure) {
18 def dsl = new PaintingDsl(length, width)
19 dsl.show()
20 }
21
22 static def pad(Closure closure) {
23 pad(500, 500, closure)
24 }
25
26 def show() {
27 def panel = new JPanel() {
28 @Override
29 protected void paintComponent(Graphics g) {
30 super.paintComponent(g)
31 g.setColor(Color.RED)
32 g.drawLine(0, 0, 100, 100)
33 }
34 }
35
36 def frame = new JFrame()
37 frame.contentPane = panel
38 frame.setSize(length, width)
39 frame.setLocationRelativeTo(null)
40 frame.defaultCloseOperation = JFrame.EXIT_ON_CLOSE
41 frame.visible = true
42 }
43}
将DSL定义更改成上面这样，就可以绘制第一条红色线段了。
Step2 设定size
给pad设置size应该实现两种方式，第一种就是新建的时候传入大小参数，第二种是在pad的内容中设定。第一种在刚才的部分已经实现了，着重来看第二个：
1pad {
2 size {
3 length = 500
4 width = 500
5 }
6}
一旦出现大括号，就要当做闭包类型的参数，传递给前面的函数。于是这里应该有一个名为size的函数，接收一个闭包参数。之后有一种做法是，使用一个字典成员变量，将闭包中的变量复制全部记录到字典中。
同时要在pad函数中，将closure的delegate指向刚实例化的PaintingDsl对象，让size能够调用到PaintingDsl的成员函数。
1package top.claws
2
3import javax.swing.JFrame
4import javax.swing.JPanel
5import java.awt.Color
6import java.awt.Graphics
7
8class PaintingDsl {
9 def sizeMap = [:]
10
11 PaintingDsl(length, width) {
12 sizeMap.length = length
13 sizeMap.width = width
14 }
15
16 static def pad(def length, def width, Closure closure) {
17 def dsl = new PaintingDsl(length, width)
18 closure.delegate = dsl
19 closure.resolveStrategy = Closure.DELEGATE_ONLY
20 dsl.show()
21 }
22
23 static def pad(Closure closure) {
24 pad(500, 500, closure)
25 }
26
27 def size(Closure closure) {
28 // 等同于设置delegate到sizeMap并执行闭包
29 sizeMap.with closure
30 }
31
32 def show() {
33 def panel = new JPanel() {
34 @Override
35 protected void paintComponent(Graphics g) {
36 super.paintComponent(g)
37 g.setColor(Color.RED)
38 g.drawLine(0, 0, 100, 100)
39 }
40 }
41
42 // ...
43 }
44
45 // 下面这两个方法用来占位 避免报错
46 def line(Closure closure) {
47 // TODO
48 }
49
50 def color(def color) {
51 // TODO
52 }
53}
运行之前的测试脚本，发现其中一个窗口确实变大了。
Step3 添加线条
可以使用一个容器记录所有要添加的线条，然后在pad内容结束后，绘图时，统一添加到panel中。
对于line块的处理，也要使用闭包，而line块中的内容将被作为新闭包的delegate的方法被实现出来。因此这里需要增加一个新的闭包以及新的LineDsl类。同时添加一个Line类方便线段管理。
为了简洁，下面只记录增加的部分。
1class PaintingDsl {
2 def lineList = []
3
4 def line(Closure closure) {
5 def dsl = new LineDsl(this)
6 closure.delegate = dsl
7 closure.resolveStrategy = Closure.DELEGATE_ONLY
8 closure()
9 }
10
11 // 更改一下绘图逻辑，绘制列表中的所有线段
12 def show() {
13 def panel = new JPanel() {
14 @Override
15 protected void paintComponent(Graphics g) {
16 super.paintComponent(g)
17 g.setColor(Color.RED)
18 for (def line in lineList) {
19 g.drawLine(line.xFrom, line.yFrom, line.xTo, line.yTo)
20 }
21 }
22 }
23 // ...
24 }
25}
26
27class LineDsl {
28 def paintingDsl
29 def lineBuilding
30
31 LineDsl(def paintingDsl) {
32 this.paintingDsl = paintingDsl
33 }
34
35 def start(x, y) {
36 lineBuilding = new Line()
37 lineBuilding.xFrom = x
38 lineBuilding.yFrom = y
39 this
40 }
41
42 def end(x, y) {
43 lineBuilding.xTo = x
44 lineBuilding.yTo = y
45 paintingDsl.lineList.add(lineBuilding)
46 lineBuilding = null
47 }
48}
49
50class Line {
51 def xFrom
52 def yFrom
53 def xTo
54 def yTo
55 def color
56}
Step4 处理颜色
只需要有一个成员变量记录当前在用的颜色就可以了。由于传进来的是一个字符串，可以使用一个static的字典记录颜色名称和对应颜色对象的映射关系。
之后再稍微修改LineDsl中end的逻辑，在线段结束的时候标上颜色。然后更改一下绘图的逻辑，遍历线段时对颜色进行重新设置即可。
1class PaintingDsl {
2 def curColor = colorMap.black
3
4 static colorMap = [
5 red : new Color(255, 175, 175),
6 black: new Color(0, 0, 0),
7 white: new Color(255, 255, 255)
8 ]
9
10 def color(String color) {
11 curColor = colorMap[color]
12 }
13
14 def show() {
15 def panel = new JPanel() {
16 @Override
17 protected void paintComponent(Graphics g) {
18 super.paintComponent(g)
19 for (def line in lineList) {
20 g.setColor(line.color)
21 g.drawLine(line.xFrom, line.yFrom, line.xTo, line.yTo)
22 }
23 }
24 }
25 // ...
26 }
27}
28
29class LineDsl {
30 def end(x, y) {
31 lineBuilding.xTo = x
32 lineBuilding.yTo = y
33 lineBuilding.color = paintingDsl.curColor // 给线段记录颜色
34 paintingDsl.lineList.add(lineBuilding)
35 lineBuilding = null
36 }
37}
成果展示
完成了所有代码的编写之后，之前的脚本中的需求就全部达成了，效果如下图： 
这个小实践中涉及的代码：https://gist.github.com/jingjiecb/e3c049ea6e463d9f06a45e879ea0878a